今回は、Tera Termを使って実際にシリアル通信対応のハンディスキャナと

通信を行い、読み取ったバーコードの情報を受け取れるか検証したので、

紹介していきます。

ちなみにTera Termのインストールについてはこちら

【ツール紹介】TeraTermをインストールしてシリアル通信テストを行う～インストール編～

TeraTermを使ってVB.Netで作成したシリアル通信テストアプリケーションをテストするためにTeraTermというツールをインストールしたので方法を紹介しています。

dreamparadaisu.com

2021-06-24 15:54

ハンディスキャナ

ハンディスキャナはレジの横についている、

バーコードやQRコードを読取ってくれる機械です。

バーコードの読み取り機能は、スマートフォンにもついていますね。

ですが、ハンディスキャナはコロナの影響もあって最近ではあらゆるところで

見かけるのではないでしょうか？

今回は、シリアル通信に対応しているハンディスキャナを使って、

データの受信の検証をしています。

シリアル通信に対応しているハンディスキャナは、

プログラムによる制御もできるのでアプリケーション開発では、

よく使うハードウェアとして、筆者の中では挙げられます。

使用したハンディスキャナは、Honeywell社から販売されている、

Xeonシリーズの1900になります。

これは、1次元コード(バーコード)や2次元コード(QR)の読み取りが可能です。

また、OCR読み取り機能も付いているので、文字を認識することもできます。

Tera Termを使った通信

ここからは既にTera Termがインストールされている前提で進めていきます。

まず、Tera Termを起動します。

起動すると、新しい接続と書かれたウィンドウが立ち上がっているかと思います。

デフォルトではTCP/IPにチェックが入っているので、

シリアルにチェックを入れます。

ポートの設定

チェックを入れ、ポートのプルダウンを押し、

パソコンに接続されているスキャナのポートを選択します。

ここではCOM6に、Xeon 1900が割り当てられています。

ユーザによってCOMの割り当ては変わりますので、気を付けてください。

設定ができたら、OKボタンを押します。

問題なく接続ができると、以下の画面が表示されます。

通信条件の確認

接続ができたら、まずは通信条件の確認を行います。

ここでいう通信条件は、

• 通信速度(ボーレート)
• データビット
• パリティ
• ストップビット

になります。

Tera Termで確認するには、設定タブをのシリアルポートを選択します。

選択すると、以下の画面が表示されます。

この画面に書いてある情報が、現在繋がれているスキャナの通信条件になります。

スピードと書かれているのが、通信速度にあたります。

読み取ったデータを受信

Tera Term上の通信条件がハンディスキャナとの通信条件が一致していれば、

データは正しく受診することができます。

受診ができない原因として挙げられるのが、

• 通信速度が一致していない
• COMが違っている
• デリミタの設定が違う

といった原因が考えられます。

※たまにパソコンと接続しているケーブルが抜けていたということもあります。

読み取る対象は、QRコードとします。

右のQRコードを読んで、Tera Term上に表示されれば、受信成功です。

受信に成功すると、読み取った情報が表示されます。

今回は、QRコードから12345678を読取り、Tera Termで受信、表示をしています。

再度読み取る場合は、バッファのクリアをして行います。

バッファのクリアは、編集タブをクリックし、バッファのクリアを選択することでできます。

以上が、受信の検証になります。

シリアル通信に関しては、こちらもご参照ください。

【VB.Net】ハードウェアとシリアル通信をする方法

PCと何らかの機器をシリアル通信(RS-232C、RS-422やRS-485)をし、データを受信したい場合や機器を制御したい場合は、IoT時代の到来よりも前に行われてきました。今回はVB.Netで何らかの機器とシリアル通信をする方法を簡単に紹介していきます。

dreamparadaisu.com

2021-01-16 17:45

まとめ

ハンディスキャナを使ってTera Termで読み取った情報が受信でき、

表示されるかといった検証を行いました。

シリアル機器の接続テストやデータ受信テストにTera Termを使うと便利です。

実際にここで接続ができれば、アプリケーションでも通信条件さえ合わせてしまえば、

通信はできるのでアプリケーションでの検証の工数が少し削減できます。

興味のある方は一度試してもらえたらなと思います。

最後までお読みいただきありがとうございます。

今回は前回の記事の応用例といった形になります。

ArduinoProMini互換機とCdsと呼ばれる明るさセンサを用いて、

室内の明るさを計測し、Cdsからの値をArduinoProMini互換機を経由し

シリアル通信で受信します。

受信した値をリアルタイムでチャートコントロールに表示するといった内容の

実験をしてみましたので紹介していきます。

ちなみに前回はこちら

【VB.Net】Arduinoとシリアル通信してみた～ArduinoProMini互換機～

Arduinoとは、イタリアで産まれた教育用のマイコンボードです。今回はArdunioProMiniの互換機とされるAE-ATMEGA328-MINIを使って、VB.Netでシリアル通信をし、ATMEGA328MINIからデータを受信する方法を紹介しています。

dreamparadaisu.com

2021-01-19 01:43

準備編

VisualStudio2019を使って、Windowsフォームアプリケーションを作成していきます。

最初の手順については、下記記事をご参照ください。

VisualStudioで始めるWindowsアプリケーション開発

VisualStudioを使ってWindowsアプリケーションを開発していく流れを紹介します。 以前に、簡単にざっくりと教える機会があった...

dreamparadaisu.com

2020-08-22 17:45

Cdsとは

硫化カドミウムセルと呼ばれ、硫黄(元素記号：S)とカドミウム(cd)の化合物になります。

下図の表面の受光部分に光を受けると明るさによって、抵抗値を低くする特性があります。

Cdsセンサ

特徴としては、

• 受光した際の反応が遅い
• 応答性を必要とする用途には不得手

といった特徴が挙げられます。

特性を利用して、暗いときに自動的に光っていく自動照明灯などに用いられたりしています。

CdsとArduinoProMini互換機の接続

ArduinoProMini互換機とCdsは以下のように接続しました。

Cdsは光を効率よく受け取れるよう黒い筒を被せています。

互換機のA01端子にCdsを接続します。

A01端子はアナログピンと呼ばれ、Cdsで受け取った値をアナログ値で取得します。

互換機はA0～A7までの8ピンが搭載されています。

フォームの作成

今回は以下のようなフォームを作成します。

各1～8までのコントロールの名称やテキストは以下のように設定しています。

実行環境

筆者の実行環境は、

• VisualStudio2019
• Windows 10 64bit
• .Net Framework 4.5.1

になります。

※　Windows7 8 8.1でも動作はできますが、

画面デザインの表示が変わるかもしれません。

アプリケーションの目的

ArudinoProMini互換機に接続されたCdsの計測値をシリアル通信を介し、

受信することでrtxSerialとchPhotoにそれぞれ表示できることを目的とします。

rtxSerialでは受け取った値を表示、chPhotoでは値を折れ線グラフ化することとします。

プログラム編

ArduioProMini互換機のスケッチ

AruduinoIDEを使用して、スケッチを作成していきます。

スケッチは前回作成したスケッチを使用していきます。

定数・変数の宣言

Cdsがつながっているピン情報を定数、Cdsからの値を記憶するのを変数として

それぞれ宣言します。

const int Cds = 1;  // Cdsがつながっているピン
int val = 0;        // Cdsからの値を記憶する変数

setup()ブロックでの処理

シリアルポートの設定を行います。

void setup()
{
  Serial.begin(9600);  //シリアルポートを9600bpsで開く
}

loop()ブロックでの処理

Cdsからの値を変数で受け取ります。

Cdsの値を受け取るには、

と記述することで受け取ることができます。

ArduinoProMiniでは、0～1023の範囲でアナログ値(整数値)を受け取ることができます。

これはアナログピンが10ビットのAD(アナログ・デジタル)コンバータを搭載しているからです。

受け取った値はSerial.printlnに引数として渡します。

これを1秒間隔で実行するようにします。

以下がloop()ブロック内のコードになります。

void loop()
{
  val = analogRead(Cds);  // Cdsの値を受け取る
  Serial.println(val);
  delay(1000);  //1秒停止
}

以上が、今回のスケッチとなります。

VB.Netのコード

定数・変数宣言

定数には、履歴の上限を50件としたいのであらかじめ宣言しておきます。

変数には、Comポートの選択値を代入する変数と

受け取った情報を記憶する変数そして受け取ったデータを

格納しておくコレクション(キュー)をそれぞれ変数として宣言します。

#Region "定数宣言"
    Private Const MAX_HISTORY As Integer = 50
#End Region

#Region "変数宣言"
    Private _comPort As String
    Private mrecvData As String = ""

    'センサ値データの履歴
    Private countHistory As Queue(Of Integer) = New Queue(Of Integer)
#End Region

フォームロード時の処理

以下の処理を行います。

• タイマーの非アクティブ
• COMポートの取得をし、コンボボックスへ反映
• チャートの表示を初期化

#Region "画面ロード"
    Private Sub frmMain_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Timer1.Enabled = False

        'COMポートを取得
        _comPort = ""
        For Each sp As String In My.Computer.Ports.SerialPortNames
            Me.cbComPort.Items.Add(sp)
        Next sp

        'チャートの表示を初期化
        Call InitializeChart()
    End Sub
#End Region

チャートの表示を初期化する部分は関数として新たに作成しています。

初期化の関数

今回はチャートを計測機器に表示されているかのようなモニタデザインにしていきます。

こんなイメージにしていきます。

#Region "グラフ表示の初期化"
    Private Sub InitializeChart()

        With chPhoto
            'チャート全体の背景色を設定
            .BackColor = Color.Black
            .ChartAreas(0).BackColor = Color.Transparent

            'チャート表示エリア周囲の余白をカットする
            .ChartAreas(0).InnerPlotPosition.Auto = False
            .ChartAreas(0).InnerPlotPosition.Width = 100       ' 100%
            .ChartAreas(0).InnerPlotPosition.Height = 90       ' 90 %(横軸のメモリラベル印字分の余白)
            .ChartAreas(0).InnerPlotPosition.X = 8
            .ChartAreas(0).InnerPlotPosition.Y = 0

            'X,Y軸情報のセット関数を定義
            Dim setAxis As Action(Of DataVisualization.Charting.Axis) =
                Sub(axisInfo)
                    '軸の目盛ラベルのフォントサイズ上限値を制限
                    axisInfo.LabelAutoFitMaxFontSize = 8

                    '軸のメモリラベルの文字色をセット
                    axisInfo.LabelStyle.ForeColor = Color.White

                    '軸タイトルの文字色をセット
                    axisInfo.TitleForeColor = Color.White

                    '軸の色をセット
                    axisInfo.MajorGrid.Enabled = True
                    axisInfo.MajorGrid.LineColor = ColorTranslator.FromHtml("#008242")
                    axisInfo.MinorGrid.Enabled = False
                    axisInfo.MinorGrid.LineColor = ColorTranslator.FromHtml("#008242")
                End Sub

            'X,Y軸の表示方法を定義
            setAxis(.ChartAreas(0).AxisY)
            setAxis(.ChartAreas(0).AxisX)

            .ChartAreas(0).AxisY.MinorGrid.Enabled = True
            .ChartAreas(0).AxisY.Maximum = 1023 '縦軸の最大値を1023にする

            .AntiAliasing = DataVisualization.Charting.AntiAliasingStyles.None

            '折れ線グラフとして表示
            .Series(0).ChartType = System.Windows.Forms.DataVisualization.Charting.SeriesChartType.Line

            '線の色を指定
            .Series(0).Color = ColorTranslator.FromHtml("#00FF00")

            '凡例を非表示、各値に数値を表示しない
            .Series(0).IsVisibleInLegend = False
            .Series(0).IsValueShownAsLabel = False

        End With
    End Sub
#End Region

シリアル通信に関連する処理

ハードウェアとの接続に関しては以下の処理を行います。

• Connectボタン押下
• シリアル通信の準備
• シリアル通信の開始 既に接続されている場合は、通信を閉じる処理を実行します。
• 接続確立後ボタンのテキストをDis-connectに変更
• タイマーの設定(1秒周期でチャートの再描画を行います。)

#Region "コネクトボタンクリック"
    Private Sub btConnect_Click(sender As Object, e As EventArgs) Handles btConnect.Click
        If (btConnect.Text = "Connect") Then
            If (_comPort <> "") Then
                Me.SerialPort1.Close()
                Me.SerialPort1.PortName = _comPort
                With Me.SerialPort1
                    .BaudRate = 9600
                    .DataBits = 8
                    .Parity = Parity.None
                    .StopBits = StopBits.One
                    .Handshake = Handshake.None
                    .Encoding = System.Text.Encoding.Default
                    .ReadTimeout = 10000
                End With

                Me.SerialPort1.Open()
                btConnect.Text = "Dis-connect"

                '1秒周期でチャートを再描画
                Timer1.Enabled = True
                Timer1.Interval = 50
                lblTimer.Text = "Timer: ON"
            Else
                MsgBox("Select a COM port first")
            End If
        Else
            Me.SerialPort1.Close()
            Me.btConnect.Text = "Connect"
            Me.Timer1.Enabled = False
            Me.lblTimer.Text = "Timer: OFF"
        End If
    End Sub
#End Region

データの受信に関する処理の流れは以下のようにします。

• データを受信 受け取った値が0ならnothing & vbcrlf(改行コード)を戻り値として返します。 0でなければ、受け取った値を整数型に変換し、戻り値として返します。

#Region "シリアルデータ受信処理"
    Private Function ReceiveSerialData(ByRef value As Integer) As String
        Dim Incoming As String
        Incoming = SerialPort1.ReadLine()
        If Incoming Is Nothing Then
            value = 0
            Return "nothing" & vbCrLf
        Else
            value = CInt(Incoming)
            Return Incoming
        End If
    End Function
#End Region

チャートコントロールの処理

1秒間隔で再描画を行うので、タイマーイベントの処理は以下のようにしました。

• コレクション変数に受け取った値を格納
• rtxSerialに受け取った値を表示
• コレクション変数が格納許容数を超えていたら格納した値を取り除く
• グラフの再描画

これらの処理を行います。

#Region "タイマー処理"
    Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
        Dim value As Integer
        mrecvData = ReceiveSerialData(value)
        rtxSerial.Text &= mrecvData
        countHistory.Enqueue(value)

        '履歴の最大数を超えていたら、古いものを削除する
        While countHistory.Count > MAX_HISTORY
            countHistory.Dequeue()
        End While

        'グラフを再描画する
        Call showChart()
    End Sub
#End Region

履歴の最大数を超えていたら、コレクション変数に最初に格納された値から取り除きます。

以降、同様の処理を1秒ごとに繰り返します。

グラフへの描画処理は以下の関数を作成し行います。

#Region "グラフの描画"
    Private Sub showChart()
        'チャートに値をセット
        chPhoto.Series(0).Points.Clear()
        For Each value As Integer In countHistory
            chPhoto.Series(0).Points.Add(New DataPoint(0, value))
        Next value
    End Sub
#End Region

実行編

実際にArduinoProMini互換機と接続して、プログラムを実行していきます。

プログラム起動時

COMポートの選択

接続後の明るさ受信

接続後の明るさ受信(数分経過後)

Cdsにライトを照らしたり、指でCdsを覆ったりして明るさを変化させてみました。

うーん、データの受信にインターバルを設定しているせいか、

スムーズな受信ができていない気がします。

これは改善の余地がありです。

※　もしコードを試される方がいましたらお気を付けください。

まとめ

ArduinoProMini互換機とCdsを使って計測値を受信し、チャートコントロールで

リアルタイムに可視化することができました。

PCとArduinoProMini互換機の通信が同期していないせいか、タイミングによっては

受信できなくなったり、チャートコントロールでの表示が遅れたりとしてしまいました。

まだまだ勉強と改善が必要です……。

読者の方の何らかの参考になれば嬉しいです。

最後までご覧いただきありがとうございます。

・こちらの書籍を参考にVB.Net勉強しています。

Visual Basic 2019 パーフェクトマスター

金城俊哉

3,300円(04/24 15:46時点)

楽天ブックス

作って覚える Visual Basic 2019 デスクトップアプリ入門

荻原 裕之, 宮崎 昭世

2,860円(04/24 15:46時点)

楽天ブックス

かんたんVisual　Basic改訂2版

高橋広樹

2,904円(04/24 15:46時点)

楽天ブックス

今回は、ArduinoProMiniの互換機であるAE-ATMEGA328-MINIを入手したので、

VB.Netで作成したアプリケーションとシリアル通信をし、

ArduinoProMini互換機からデータを受信してみたので紹介していきます。

ちなみに前回はこちら

【VB.Net】ハードウェアとシリアル通信をする方法

PCと何らかの機器をシリアル通信(RS-232C、RS-422やRS-485)をし、データを受信したい場合や機器を制御したい場合は、IoT時代の到来よりも前に行われてきました。今回はVB.Netで何らかの機器とシリアル通信をする方法を簡単に紹介していきます。

dreamparadaisu.com

2021-01-16 17:45

前回紹介できなかったシリアル通信後のデータ受信についても、こちらで触れています。

準備編

VisualStudio2019を使って、Windowsフォームアプリケーションを作成していきます。

最初の手順については、下記記事をご参照ください。

VisualStudioで始めるWindowsアプリケーション開発

VisualStudioを使ってWindowsアプリケーションを開発していく流れを紹介します。 以前に、簡単にざっくりと教える機会があった...

dreamparadaisu.com

2020-08-22 17:45

フォームの作成

フォームについては、前回のフォームを使います。

各1～21までのコントロールの名称やテキストは以下のように設定しています。

実行環境

筆者の実行環境は、

• VisualStudio2019
• Windows 10 64bit
• .Net Framework 4.5.1

になります。

※　Windows7 8 8.1でも動作はできますが、

画面デザインの表示が変わるかもしれません。

アプリケーションの目的

各通信パラメータを選択し、接続ボタンを押すことで

ArduinoProMini互換機と接続ができることを確認し、

データが受信できることを目的とします。

プログラム編

シリアル通信の接続に関する処理は、前回の記事をそのまま使用します。

ここでは、ArduinoProMini互換機側のコードと

データ受信に関する処理について書いていきます。

ArduinoProMini互換機へのプログラム

今回使用するArduinoProMini互換機は以下のようなマイコンとなっております。

ArduinoProMini互換機

ArduinoIDEの準備

ArduinoProMini互換機のプログラム(コード)を書くには、統合開発環境の

ArduinoIDEを使用します。

IDEについては、Arduinoの公式フォーラムからダウンロードしてください。

Arduino IDE(Arduino公式ページ)

ダウンロードをし、インスト―ルが完了すると

デスクトップ上に下のショートカットアイコンが作成されます。

※場合によっては、作成されないかもしれません。

問題なくインストールされ、ショートカットアイコンを実行すれば、

以下のような画面が表示されると思います。

PCとArduinoProMini互換機を接続する

PCとArduinoProMini互換機を接続するにあたって、互換機だけでは接続ができないので

以下のボードを使います。

FT-232RQ USBシリアル変換モジュール

背面

こちらを使って、以下のようにArduinoProMini互換機と接続してPCと接続をします。

ArduinoProMini互換機とUSBシリアルモジュールの接続図

USBシリアルモジュールとマイクロUSB(オス)-USB(オス)の接続図

ArduinoIDE上での接続設定

PCに接続をしたら、ツールタブ→ボード→Arduino Pro or Pro Miniを選択します。

次にArduinoIDEのツールタブ→プロセッサ→ATmega328P(5V, 16MHz)を選択します。

最後に、ツールタブ→シリアルポート→COM3を選択します。

※COM以降の数字に関しては、各端末によって異なります。

筆者の環境ではCOM3にArduinoProMini互換機が接続されています。

これで接続の設定は完了になります。

ArudinoProMini互換機側のスケッチを作成する

ArduinoIDEではスケッチと呼ばれるキャンパスを使ってコードを書いていきます。

VB.Netでいうプロジェクト(+ソースファイル)にあたる部分になります。

作成時には、setup()ブロックとloop()ブロックがコードとして書かれています。

setup()ブロックには、主に通信時の設定やピンの割り当て(設定)などの処理を記述します。

loop()ブロックでは、LEDの制御やデータの受送信などのメインとなる処理を記述します。

今回はシリアル通信に関する処理を書いていきます。

setup()ブロックでの記述

setup()ブロックでは、ボーレートを設定します。

設定するには、Serial.begin(設定したいボーレート)で行います。

void setup()
{
  Serial.begin(9600);  //シリアルポートを9600bpsで開く
}

setup()ブロックはこれで完了です。

loop()ブロックでの記述

loopブロックでは、送信するデータとして、文字列”Hello”と設定します。

これには、Serial.println(“Hello”)と記述します。

データの送信間隔を1秒とし、1秒間隔でHelloを送信する処理を行わせます。

送信間隔を設定するには、delay(ミリ秒)関数を使用します。

1秒なので、1000ミリ秒を引数として渡します。

delay(1000)と記述します。

コードで書くと以下のようになります。

void loop()
{
  Serial.println("Hello");
  delay(1000);  //1秒停止
}

これでArduinoProMini側のスケッチは完了になります。

スケッチのボードへの書き込み

完了したスケッチをボードへ書き込みます。

書き込むには、以下の流れで行います。

1. 作成したスケッチの検証(コンパイル)
2. ボードに書き込む

1では、コードにエラーがないか検証を行っています。

問題がなければ、ボードに書き込んでいきます。

問題がなければ

もし、コードに問題がある場合はエラーが表示されます。

書き込みボタンを押します。

問題がなければ、

書き込み中にエラーが発生してしまうと、

この場合PCとの接続が途切れてしまった(途中でケーブルが抜けてしまった)が考えられます。

以上の流れで、作成したスケッチをボードに書き込むことができます。

シリアル通信のデータ受信処理

ここからはVB.Netに戻り、シリアル通信後のデータを受信する場合は、

SerialPort変数.ReadLine()で受け取ることができます。

今回は、ArduinoProMini互換機から受け取った値は

Console.WriteLine()で出力をするようにします。

前回記事で紹介した、以下のコードを使用します。

#Region "データ受信イベント"
    Private Sub mSerialPort_DataReceived(ByVal sender As System.Object, ByVal e As System.IO.Ports.SerialDataReceivedEventArgs) Handles mSerialPort.DataReceived

            '受信データ格納変数
            Dim mRecvData As String = mSerialPort.ReadLine()

            Console.WriteLine(mRecvData)

    End Sub
#End Region

実行編

ArduinoProMini互換機の通信設定は以下の設定としています。

• 通信速度(ボーレート)：9600bps
• データ長(データビット)：8ビット
• パリティ：なし(None)
• ストップビット：1ビット
• COMポート名：COM3(※接続する端末によって異なります。)

起動時

書くパラメータ設定後、接続ボタンを押します

VisualStudio2019に戻り、出力ウィンドウにデータが表示されていることを確認します。

1秒間隔でHelloが受信できていることが確認できます。

まとめ

シリアル通信でデータを受信する方法とArduinoProMini互換機の統合開発環境(ArduinoIDE)

の使い方やArduino言語のシリアル通信に関する処理について解説しました。

Arduino関連でWindowsフォームアプリケーションと

シリアル通信をしてみたかった読者、初学者の方の少しでも参考になれば嬉しいです。

最後までご覧いただきありがとうございます。

・こちらの書籍を参考にVB.Net勉強しています。

Visual Basic 2019 パーフェクトマスター

金城俊哉

3,300円(04/24 15:46時点)

楽天ブックス

作って覚える Visual Basic 2019 デスクトップアプリ入門

荻原 裕之, 宮崎 昭世

2,860円(04/24 15:46時点)

楽天ブックス

かんたんVisual　Basic改訂2版

高橋広樹

2,904円(04/24 15:46時点)

楽天ブックス

今回はVB.Netで何らかの機器とシリアル通信をする方法について、

例を交えて簡単に紹介していきます。

シリアル通信を学んで様々な機器と接続をし、危機からのデータの取得や

機器の制御などができるようになるお手伝いができればなと思っております。

ちなみに前回はこちら

【VB.Net】Chartコントロールの使い方～疑似計測編～

Chartコントロールを使うことでWindowsフォームアプリケーションでグラフを作成・表示ができます。ここではChartの使い方を簡単に、疑似的に生成されたデータをボタンを押すたびにプロットしていくといった例を交えて紹介しています。

dreamparadaisu.com

2021-01-15 00:59

準備編

VisualStudio2019を使って、Windowsフォームアプリケーションを作成していきます。

最初の手順については、下記記事をご参照ください。

VisualStudioで始めるWindowsアプリケーション開発

VisualStudioを使ってWindowsアプリケーションを開発していく流れを紹介します。 以前に、簡単にざっくりと教える機会があった...

dreamparadaisu.com

2020-08-22 17:45

シリアル通信とは

インターネットで検索すると、以下のような回答がヒットします。

シリアル通信（シリアルつうしん、英: Serial communication）は、電気通信において伝送路上を一度に1ビットずつ、逐次的にデータを送ることをいう。

出典: フリー百科事典『ウィキペディア（Wikipedia）』

1ビットは0や1のデータを指します。

シリアル通信には以下の規格があります。

• RS-232C D-Sub25ピンまたはD-Sub9ピン(接続コネクタ) 正式名称：ANSI/EIA-232-E
• RS-422A 各信号線の目的やタイミングは規定されています。 接続コネクタの規定はありません。 主にD-Sub25ピンやD-Sub9ピンが採用されています。
• RS-485 RS-422Aの上位互換の規格 正式名称：EIA-485

といった規格があり、主にはRS-232やRS-485が使われているのではないでしょうか。

主なパラメータごとの特徴は以下のようになります。

フォームの作成

今回、以下のフォームを作成します。

各1～21までのコントロールの名称やテキストは以下のように設定しています。

実行環境

筆者の実行環境は、

• VisualStudio2019
• Windows 10 64bit
• .Net Framework 4.5.1

になります。

※　Windows7 8 8.1でも動作はできますが、画面デザインの表示が変わるかもしれません。

アプリケーションの目的

各通信パラメータを選択し、接続ボタンを押すことで機器との接続が成功した場合には、

rtxSerialに接続成功が出ることを確認し、

データが受信できる機器であれば受信ができることを目的とします。

受信ができない場合は、接続のみ確認できることを目的とします。

プログラム編

定数・変数宣言

定数と変数には、それぞれ通信パラメータで必要となる変数を準備します。

#Region "定数宣言"
    Private Const DataLength_Seven As Integer = 7
    Private Const DataLength_Eight As Integer = 8
#End Region

#Region "変数宣言"
    Private mBaudRate As Integer = Nothing　　　　　' 通信速度(機器側)
    Private mDataLength As Integer = Nothing      ' データ長
    Private mStopBits As StopBits = Nothing       ' ストップビット 
    Private mParity As Parity = Nothing           ' パリティ
    WithEvents mSerialPort As SerialPort = Nothing     ' 通信用シリアルポート変数
#End Region

#Region～#End Regionと書くことで、コードをわかりやすいように

ブロックごとに分けています。(今までの記事では書いていませんでした。。。)

通信速度用に以下の列挙体を準備しておきます。

#Region "列挙体"
    Public Enum BaudrateList
        BR1 = 57600
        BR2 = 38400
        BR3 = 19200
        BR4 = 9600
        BR5 = 4800
    End Enum
#End Region

フォーム起動時の処理

フォーム起動時には以下の処理を行います。

#Region "画面ロード"
    Private Sub frmMain_Load(sender As Object, e As EventArgs) Handles MyBase.Load

            'コムポート取得
            Call SetComPort()


    End Sub
#End Region

PCに接続されているCOMポートを取得する関数を作成し、呼び出しています。

COMポート取得関数

COMポートを取得し、コンボボックスのcbComportに値をセットしています。

#Region "COMポート処理"
    ''' <summary>
    ''' コンボボックスへ接続されているCOMを追加
    ''' </summary>
    Private Sub SetComPort()
        Dim subName As String = "SetComPort"
        For Each strComPort As String In SerialPort.GetPortNames
            cbComport.Items.Add(strComPort)
        Next strComPort
    End Sub
#End Region

ボタン押下時の処理

ボタンが押されたら、以下の処理を行います。

• SerialPort変数の初期化
• 各通信パラメータ(ストップビット、パリティ除く)入力値チェック
• シリアル通信開始
• 成功時、接続成功とrtxSerialに表示

#Region "ボタン押下処理"
    ''' <summary>
    ''' シリアル機器接続
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub btConnect_Click(sender As Object, e As EventArgs) Handles btConnect.Click
        mSerialPort = New SerialPort

            'ボーレート
            If mBaudRate = Nothing Then
                MessageBox.Show("ボーレートが選択されていません。")
                Return
            End If
            mSerialPort.BaudRate = mBaudRate

            'データビット
            If mDataLength = Nothing Then
                MessageBox.Show("データ長が選択されていません。")
            End If
            mSerialPort.DataBits = mDataLength

            'COMポート
            If cbComport.Text = "" Then
                MessageBox.Show("COMポートが選択されていません。")
                Return
            End If
            mSerialPort.PortName = cbComport.SelectedItem.ToString()

            'シリアル接続
            mSerialPort.Open()

            rtxSerial.Text = "接続成功"

    End Sub

通信パラメータに関する処理

シリアル通信の接続をするにあたって、通信時のパラメータがあります。

このパラメータが通信側の機器とあっていないと正しく通信ができないので、

注意が必要です。

通信パラメータには主に以下の項目があります。

• 通信速度(ボーレート[bit/sec])
• データ長(DataBits)
• パリティ(Parity)
• ストップビット(StopBits)
• COMポート

各通信パラメータのラジオボタンがチェックされたとき、以下の処理をそれぞれ行います。

ボーレート(通信速度)

#Region "ボーレート処理"
    ''' <summary>
    ''' 通信速度57600(bit/sec)
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rb57600_CheckedChanged(sender As Object, e As EventArgs) Handles rb57600.CheckedChanged
        Dim subName As String = "rb57600_CheckedChanged"
        If rb57600.Checked Then
            Me.mBaudRate = BaudrateList.BR1
        Else
            Me.mBaudRate = Nothing
        End If
    End Sub

    ''' <summary>
    ''' 通信速度38400(bit/sec)
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rb38400_CheckedChanged(sender As Object, e As EventArgs) Handles rb38400.CheckedChanged
        Dim subName As String = "rb38400_CheckedChanged"
        If rb38400.Checked Then
            Me.mBaudRate = BaudrateList.BR2
        Else
            Me.mBaudRate = Nothing
        End If
    End Sub

    ''' <summary>
    ''' 通信速度19200(bit/sec)
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rb19200_CheckedChanged(sender As Object, e As EventArgs) Handles rb19200.CheckedChanged
        Dim subName As String = "rb19200_CheckedChanged"
        If rb19200.Checked Then
            Me.mBaudRate = BaudrateList.BR3
        Else
            Me.mBaudRate = Nothing
        End If
    End Sub

    ''' <summary>
    ''' 通信速度9600(bit/sec)
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rb9600_CheckedChanged(sender As Object, e As EventArgs) Handles rb9600.CheckedChanged
        Dim subName As String = "rb9600_CheckedChanged"
        If rb9600.Checked Then
            Me.mBaudRate = BaudrateList.BR4
        Else
            Me.mBaudRate = Nothing
        End If
    End Sub

    ''' <summary>
    ''' 通信速度4800(bit/sec)
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rb4800_CheckedChanged(sender As Object, e As EventArgs) Handles rb4800.CheckedChanged
        Dim subName As String = "rb4800_CheckedChanged"
        If rb4800.Checked Then
            Me.mBaudRate = BaudrateList.BR5
        Else
            Me.mBaudRate = Nothing
        End If
    End Sub
#End Region

データ長(データビット)

#Region "データビット処理"
    ''' <summary>
    ''' データビット　7ビット
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbSeven_CheckedChanged(sender As Object, e As EventArgs) Handles rbSeven.CheckedChanged
        Dim subName As String = "rbSeven_CheckedChanged"
        If rbSeven.Checked Then
            Me.mDataLength = DataLength_Seven
        Else
            Me.mDataLength = Nothing
        End If
    End Sub

    ''' <summary>
    ''' データビット　8ビット
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbEight_CheckedChanged(sender As Object, e As EventArgs) Handles rbEight.CheckedChanged
        Dim subName As String = "rbEight_CheckedChanged"
        If rbEight.Checked Then
            Me.mDataLength = DataLength_Eight
        Else
            Me.mDataLength = Nothing
        End If
    End Sub
#End Region

ストップビット

#Region "ストップビット"
    ''' <summary>
    ''' ストップビット　1ビット
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbOne_CheckedChanged(sender As Object, e As EventArgs) Handles rbOne.CheckedChanged
        Dim subName As String = "rbOne_CheckedChanged"
        If rbOne.Checked Then
            Me.mStopBits = StopBits.One
        Else
            Me.mStopBits = Nothing
        End If
    End Sub

    ''' <summary>
    ''' ストップビット　2ビット
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbTwo_CheckedChanged(sender As Object, e As EventArgs) Handles rbTwo.CheckedChanged
        Dim subName As String = "rbTwo_CheckedChanged"
        If rbTwo.Checked Then
            Me.mStopBits = StopBits.Two
        Else
            Me.mStopBits = Nothing
        End If
    End Sub
#End Region

パリティ

#Region "パリティ処理"
    ''' <summary>
    ''' 偶数
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbEven_CheckedChanged(sender As Object, e As EventArgs) Handles rbEven.CheckedChanged
        Dim subName As String = "rbEven_CheckedChanged"
        If rbEven.Checked Then
            Me.mParity = Parity.Even
        Else
            Me.mParity = Nothing
        End If
    End Sub

    ''' <summary>
    ''' 奇数
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbOdd_CheckedChanged(sender As Object, e As EventArgs) Handles rbOdd.CheckedChanged
        Dim subName As String = "rbOdd_CheckedChanged"
        If rbOdd.Checked Then
            Me.mParity = Parity.Odd
        Else
            Me.mParity = Nothing
        End If
    End Sub

    ''' <summary>
    ''' なし
    ''' </summary>
    ''' <param name="sender"></param>
    ''' <param name="e"></param>
    Private Sub rbNone_CheckedChanged(sender As Object, e As EventArgs) Handles rbNone.CheckedChanged
        Dim subName As String = "rbNone_CheckedChanged"
        If rbNone.Checked Then
            Me.mParity = Parity.None
        Else
            Me.mParity = Nothing
        End If
    End Sub
#End Region

データ受信に関する処理

機器から何らかのデータを受信したとき、以下の処理を行います。

このアプリケーションでは、受け取った値をConsole.WriteLine()で出力します。

と記述することで通信された機器からデータを受信することができます。

また、mSerialPort.DataReceivedのイベントを書くことで、

機器からデータを受信したときにイベントが発生がされるので逐一データの出力がされます。

#Region "データ受信イベント"
    Private Sub mSerialPort_DataReceived(ByVal sender As System.Object, ByVal e As System.IO.Ports.SerialDataReceivedEventArgs) Handles mSerialPort.DataReceived

            '受信データ格納変数
            Dim mRecvData As String = mSerialPort.ReadLine()

            Console.WriteLine(mRecvData)

    End Sub
#End Region

実行編

それでは実行していきます。

プログラム起動時

通信パラメータ選択時

接続ボタン押下後、接続成功メッセージを表示

データ受信に関しては、手元になかったので後日改めて実行後書き足していきます。。。

続編として、以下の記事を作成しました。

ArduinoProMini互換機からデータを受信する記事になっています。

【VB.Net】Arduinoとシリアル通信してみた～ArduinoProMini互換機～

Arduinoとは、イタリアで産まれた教育用のマイコンボードです。今回はArdunioProMiniの互換機とされるAE-ATMEGA328-MINIを使って、VB.Netでシリアル通信をし、ATMEGA328MINIからデータを受信する方法を紹介しています。

dreamparadaisu.com

2021-01-19 01:43

まとめ

VB.Netによるシリアル通信の接続や通信先の機器からデータの受信について、

紹介していきました。

シリアル通信では通信先のパラメータが正しく合致していないと

通信が正常に行われないので通信先のパラメータを

よく確認したうえで通信をするようにしましょう。

たとえ通信ができてもボーレートの違いによってデータの受信に失敗することもあります。

読者の方の少しでも参考になれば嬉しいです。

最後までご覧いただきありがとうございます。

・こちらの書籍を参考にVB.Net勉強しています。

Visual Basic 2019 パーフェクトマスター

金城俊哉

3,300円(04/24 15:46時点)

楽天ブックス

作って覚える Visual Basic 2019 デスクトップアプリ入門

荻原 裕之, 宮崎 昭世

2,860円(04/24 15:46時点)

楽天ブックス

かんたんVisual　Basic改訂2版

高橋広樹

2,904円(04/24 15:46時点)

楽天ブックス